gparted/configure.in

AC_INIT(gparted, 0.3)
AC_CONFIG_SRCDIR(src/main.cc)
AM_INIT_AUTOMAKE

AM_CONFIG_HEADER(config.h)
AM_MAINTAINER_MODE


dnl======================
dnl checks for programs 
dnl======================
AC_PROG_CC
AC_PROG_CXX
AM_PROG_LIBTOOL

dnl======================
dnl i18n stuff 
dnl======================
GETTEXT_PACKAGE=gparted
AC_SUBST(GETTEXT_PACKAGE)
AC_DEFINE_UNQUOTED(GETTEXT_PACKAGE, "$GETTEXT_PACKAGE",[description])

ALL_LINGUAS="bg ca cs de dz el en_CA en_GB es fi fr gl he hu it ja lt lv mk ne nl pa pl pt pt_BR ru rw sv tr uk vi zh_CN zh_TW"

AM_GLIB_GNU_GETTEXT
AC_PROG_INTLTOOL


dnl======================
dnl checks for libs 
dnl======================
AC_CHECK_LIB(uuid, uuid_generate, [], AC_MSG_ERROR([*** uuid library (libuuid) not found]))
AC_CHECK_LIB(dl, dlopen,          [], AC_MSG_ERROR([*** dl library (libdl) not found]))

dnl libparted
AC_MSG_CHECKING(for libparted >= 1.7.1)
LDFLAGS=-lparted
AC_TRY_RUN(
#include <stdio.h>
#include <parted/parted.h>

int main ()
{
	int major ;
	int minor ;
	int micro ;

	if ( sscanf( ped_get_version(), "%d.%d.%d", &major, &minor, &micro ) == 3 )
		printf( "Found libparted %s\t", ped_get_version() ) ;

        return ! ( major == 1 && minor == 7 && micro >= 1 ) ;
}
,AC_MSG_RESULT(OK),AC_MSG_ERROR(*** Requires libparted >= 1.7.1) )


dnl GTKMM
PKG_CHECK_MODULES(GTKMM, gtkmm-2.4 > 2.8 )
AC_SUBST(GTKMM_LIBS)
AC_SUBST(GTKMM_CFLAGS)


AC_OUTPUT([
Makefile
compose/Makefile
include/Makefile
src/Makefile
pixmaps/Makefile
po/Makefile.in
])